ESP32 UDP Command Code Packet Sender Scheme

Ovládanie ESP32 prostredníctvom Windows aplikácie zasielaním datagramov

  • Softvér navrhnutý pre jednoduché ovládanie výstupu na vyžiadanie používateľa
  • Rozhranie pre odosielanie príkazov je akýkoľvek UDP klient, ktorý vie zasielať UDP správu - datagram, napríklad Packet Sender na Windowse.
  • Packet Sender vyžaduje úpravu konfigurácie pre validné odosielanie UDP datagramov. Navolenie možnosti pre pridanie 500ms pauzy (tzv. mód pre pomalé zariadenia).
  • Packet Sender konfigurácia - pridanie pauzy pre pomalé zariadenia
  • Nastavenie Packet Sendera je jednoduché, vyžaduje sa zadanie IP adresy, na ktorú sa dáta odosielajú, vrátane portu. (IP adresa ESP32 - dostupná vo výpise Sériovej linky - UART-u)
  • UART výstup

    Výpis sériového monitoru - obsahuje IP adresu ESP32 v LAN sieti

    Používateľské rozhranie Packet Sendera

    Packet Sender - používateľské rozhranie, tabuľka prijatých a odoslaných datagramov
  • UDP negarantuje doručenie správ. Z toho dôvodu ESP32 po obdržaní správy (ZAP/VYP) odošle správu odosielateľovi o úspešnosti prenosu. (Odosielateľ však môže správu zahodiť, alebo ju nedostať)
  • Vo výsledku je možné na vyžiadanie ovládať výstup, či už v podobe diódy, alebo relé so spínaním výkonových spotrebičov. Ovládanie je ľahké a vhodné aj pre začiatočníkov s platformou ESP32.
  • Packet Sender je možné stiahnuť na adrese: https://packetsender.com/
  • ESP32 program - UDP CONTROL (via Packet Sender)

    /*|----------------------------------------------------------------------------|*/
    /*|SKETCH PRE UDP OVLADANIE ESP32 PROSTREDNICTVOM PROGRAMU PACKET SENDER       |*/
    /*|VYHOTOVIL: MARTIN CHLEBOVEC                                                 |*/
    /*|Web: https://arduino.php5.sk/udp-control-esp32.php                          |*/
    /*|Doska: ESP32 DevkitC v4 / ESP32 Devkit v1                                   |*/
    /*|----------------------------------------------------------------------------|*/
     
    #include "WiFi.h"
    #include "AsyncUDP.h"
    const char* ssid = "WIFI_MENO";
    const char* pass = "WIFI_HESLO";
    const int led = 2; //D pin (Build-in LED pre Devkit V1)
    AsyncUDP udp;
     
    void setup()
    {
      Serial.begin(115200);
      pinMode(led, OUTPUT);
      WiFi.disconnect(true);
      WiFi.mode(WIFI_STA);
      WiFi.begin(ssid, pass);
     
      while (WiFi.status() != WL_CONNECTED) {
        delay(500);
        Serial.print(".");
      }
     
      if (udp.listen(4444)) {
        Serial.print("UDP server na IP: ");
        Serial.print(WiFi.localIP());
        Serial.println(" port: 4444");
        udp.onPacket([](AsyncUDPPacket packet) {
          Serial.print("Typ UDP datagramu: ");
          Serial.print(packet.isBroadcast() ? "Broadcast" : packet.isMulticast() ? "Multicast" : "Unicast");
          Serial.print(", Odosielatel: ");
          Serial.print(packet.remoteIP());
          Serial.print(":");
          Serial.print(packet.remotePort());
          Serial.print(", Prijimatel: ");
          Serial.print(packet.localIP());
          Serial.print(":");
          Serial.print(packet.localPort());
          Serial.print(", Dlzka spravy: ");
          Serial.print(packet.length()); //dlzka spravy
          Serial.print(", Payload: ");
          Serial.write(packet.data(), packet.length());
          Serial.println();
          String myString = (const char*)packet.data();
          if (myString.startsWith("ZAP")) {
            Serial.println("Akcia: Zapinam rele");
            digitalWrite(led, HIGH);
          } else if (myString.startsWith("VYP")) {
            Serial.println("Akcia: Vypinam rele");
            digitalWrite(led, LOW);
          }
          packet.printf("ESP32 prijalo %u bajty dat", packet.length()); //odpoved odosielatelovi
        });
      }
    }
     
    void loop()
    {
      delay(1000); //nutny delay, UDP sprava sa nestiha nacitat
    }
    

    Schéma zapojenia pre ESP32 s ovládaním UDP príkazmi

    UDP ovládanie ESP32 - schéma zapojenia